Do While～Loopの脱出方法とコードのまとめ方について質問させてください。

このプログラムはあるサイトの隠しデータに値を飛ばします。
１の値が入ると指定ディレクトリにテキストファイルを作ります。
一定時間が経過するとテキストファイルを消して隠しデータに２を飛ばすと新たな処理を始めるといったものです。

ここで悩んでいる部分があるのですがテキストファイルは１の値が入った後の処理が終われば自動に消えるのですが、ときたま消えない時があります。その判断基準は１３０秒過ぎたらおかしいです。

テキストファイルがある間はグルグルループをしていますがテキストファイルが消去されない場合無限ループに陥ってしまいます。
このプログラムの処理が開始してから１３０秒経ってもループしていたら脱出するといった方法はどのようにすればいいでしょうか？
脱出する際このプログラムでテキストを消し新たに値の１を飛ばすのを２回まで行うようにはしたいと思っています。

あとこのプログラムですが似通った部分があるなーと自分では考えてしまうのですがまとめようとするとうまく動きません。
Callで呼ぶ方法でやってみたのですが・・・プログラムのまとめ方にコツはありますか？


Set shell = CreateObject("Shell.Application")
For Each objWindow In shell.Windows
If TypeName(objWindow.document) = "HTMLDocument" Then
If objWindow.Document.URL = " ; Then
objWindow.document.getElementById("name").value = "1"
End If
End If
Next
WScript.Sleep(3000)
Set objFS = CreateObject("Scripting.FileSystemObject")
Do While objFS.FileExists("D:\test\test.txt")
WScript.sleep(250)
Loop
If objFS.FileExists("D:\test\test.txt") = False Then
Set shell = CreateObject("Shell.Application")
For Each objWindow In shell.Windows
If TypeName(objWindow.document) = "HTMLDocument" Then
If objWindow.Document.URL = " ; Then
objWindow.document.getElementById("name").value = "2"
End If
End If
Next
Set shell = Nothing
End If

'概ねこんな感じでいいと思います。

Const YAHOO_URL = "http://www.yahoo.co.jp/"
Dim objFS, start_time, progress

Set objFS=CreateObject("Scripting.FileSystemObject")

Call SetValue(1)
start_time = Now '処理をした時間
WScript.Sleep(3*1000) '３秒待つ

'指定ファイルが無くなるか、１３０秒経過するまで待つ
progress = True
Do While objFS.FileExists("D:\test\test.txt") And progress
    WScript.sleep(250) 'さらに0.25秒待つ
    '１３０秒を超えた時ループを抜ける
    progress = (Datediff("s", start_time, Now) <= 130)
Loop

If progress Then 'ファイルが無くなっている時に処理
    Call SetValue(2)
Else '時間超過による脱出時の処理
    WScript.Echo "時間経過により脱出しました"
End If
'Set objFS = Nothing

Sub SetValue(n)
    Dim shell, objWindow

    Set shell = CreateObject("Shell.Application")
    For Each objWindow In shell.Windows
        If TypeName(objWindow.Document) = "HTMLDocument" Then
            If objWindow.Document.URL = YAHOO_URL Then
                objWindow.Document.getElementById("name").value = n
            End If
        End If
    Next

    'SetShell = Nothing
End Sub